# Checker for He.2

# Check orders from the definition
chor 1 2
chor 2 6
mu 1 2 3
chor 3 30

# Check that a is in 2B
mu 3 2 4
mu 4 3 5  # abbab
mu 4 5 6  # abbabbab
chor 6 24
pwr 12 6 7   # This is a 2B element 
mu 1 7 8
chor 8 17    # Odd order, so a is in 2B.

# Check that b is in 6C. We know it is in 6CDE. We will
# show it is not in 6D or 6E by finding an element of
# order 15 which commutes with it. We first need to
# construct some elements in the centralizer of b^3 (which
# must be a 2C element).
pwr 3 2 9   # b^3
cj 9 1 10
mu 9 10 11
pwr 4 11 12  # An element of C(b^3)
cj 9 5 13
mu 9 13 14
mu 14 14 15  # Another element of C(b^3)
mu 12 15 16  # We claim this element has order 15 and commutes with b
chor 16 15
com 16 2 17
chor 17 1
